COMMENT ⊗   VALID 00002 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	  THIS PLOTS ON CALCOMP (OR TO XGP) STUFF FROM MP.DMP(DO DO.DO]
C00006 ENDMK
C⊗;
;  THIS PLOTS ON CALCOMP (OR TO XGP) STUFF FROM MP.DMP(DO DO.DO]
	TITLE PLOTIT ; ********* MAY 9,75 *********
	EXTERNAL PLOT,PLOTS

	CH3←15	;WAS ←13  4/18/75 *******

XRPT:	100000	;THESE CATCH REPEATS OF SAME POSITION. (WHEN PLOT IS SMALL)
YRPT:	100000
XMLT:	0.5	;THESE ARE MULT. FACTORS TO CHANGE SIZE OF PLOT. (OR DISTORT)
YMLT:	0.5

BEG:	JSA 16,PLOTS    ;INITS PLOT PROG.
	JUMP 2	;TYPE 'C' TO CENTER PEN, AFTER YOU MOVE IT TO LEFT.

	OUTSTR[ASCIZ/FILE NAME (DEFAULT=PLT)  /]
	INCHWL 1
	CAIN	1,15		; LOOK FOR CR.
	JRST 	DFAULT
	SETZM DIR		; THE FILE NAME WILL BE HERE.
	SKIPA 2,[POINT 6,DIR]
GOT:	INCHWL	1
	CAIGE	1,60		; CHECKS FOR GOOD CHARS.
	JRST	DONE
	SUBI	1,40
	IDPB	1,2
	JRST	GOT

DFAULT:	MOVE 1,[SIXBIT/PLT/]
	MOVEM 1,DIR
DONE:	INIT CH3,17
	SIXBIT/DSK/
	0
	0
	MOVE 0,[SIXBIT/DMD/]
	MOVEM 0,DIR+1
	SETZM DIR+2
	SETZM DIR+3
	LOOKUP CH3,DIR
	JRST CENTER
	SETZM DIR+1


INP:	HRRZI 0,M
	SUBI 0,1
	MOVEM 0,COM
	MOVNI 0,=128
	HRLM 0,COM
	INPUT CH3,COM
	STATZ CH3,740000
	0
	MOVEI 6,1
LUP:	MOVEI 5,M
	ADDI  5,(6)
	MOVE 2,(5)	; UNPAC ROUTINE
	LSHC 2,-10	; 14 BITS, 14 BITS, 8 BITS
	ASH 3,-34
	MOVEM 3,K 
	LSHC 2,-16
	ASH 3,-26
	FLTR 3,3	;MULTS Y COORD. BY YMLT
	FMPR 3,YMLT
	KIFIX 0,3
	LSHC 2,-16
	ASH 3,-26
	FLTR 3,3	;MULTS X COORD. BY XMLT
	FMPR 3,XMLT
	KIFIX 3,3
	CAMN 3,XRPT
	CAME 0,YRPT
	SKIPA
	JRST NOPLT
	MOVEM 3,I
	MOVEM 0,J 
	MOVEM 3,XRPT
	MOVEM YRPT

	JSA 16,PLOT
	JUMP I
	JUMP J
	JUMP K
NOPLT:	CAMGE 6,M
	AOJA 6,LUP

	MOVE 2,M
	CAIN 2,=127
	JRST INP
	EXIT
CENTER:	MOVE DIR    ;TYPE 'C' TO CENTER PEN.  YOU PUT IT TO FAR LEFT.
	CAME [SIXBIT/C/]
	HALT		;DIES IF FILE WAS NOT FOUND 
	OUTSTR[ASCIZ/CENTERING THE PEN /]
	JSA 16,PLOT
	JUMP [=3000]	;MOVES 15 INCHES TO RIGHT
	JUMP [0]
	JUMP [-3]
	INCHWL 1	;GET THE LINE FEED
	JRST BEG+2	;GO ASK FOR NAME AGAIN.
COM:	OCT 0,0
BLKNUM:	0


I:	0
J:	0
K:	0
M:	BLOCK =128

DIR:	BLOCK 4

	END BEG